【Windows標準】ドラッグ&ドロップでファイル分割・結合する。makecabやextrac32をバッチで実行。ハッシュ値自動チェック！

以下全てコピーしてください。

@echo off

rem ****基本設定****
rem 分割後ファイル名
set fragmentfilename=fragment*.cab
set fragmentfilename2=fragment1.cab

rem 分割ファイルの最大サイズ　512の倍数で指定。102400000=100MB
set fragmentsize=102400000
set fragmentsize2=約100MB
rem ****************

rem ■■■引数があるか確認■■■
if "%1"=="" (
 goto noarg
) else (
 goto main
)

rem 引数無しの場合
:noarg
echo 分割したいファイルを「ファイル分割.bat」へドラッグ＆ドロップしてください。
echo 処理を終了します。何かキーを押して下さい。
pause
goto end

rem 引数有の場合

rem ■■■メイン処理■■■
:main
rem バッチファイルのパスへ移動
cd %~dp0

rem フォルダ作成用の日付を準備
set time_tmp=%time: =0%
set dirname=%date:/=%%time_tmp:~0,2%%time_tmp:~3,2%%time_tmp:~6,2%

rem 引数ファイル名取得
set filename=%~nx1

rem ハッシュ値確認
rem certutil -hashfile %~f1
for /f "usebackq skip=1 delims=" %%A in (`certutil -hashfile %~f1`) do (
    set hash_before=%%A
    goto exitfor
)
:exitfor

echo %hash_before%

rem 実行確認
echo 分割前ファイル名：%filename%
echo 分割後ファイル名：%fragmentfilename%
echo 出力先　　　　　：%~dp0%dirname%
echo 分割サイズ　　　：%fragmentsize2%
echo ハッシュ値　　　：%hash_before%
set /p yn_check="ファイル分割を開始しますか？(y/n)"

if %yn_check:Y=Y%==Y (
 goto yes
) else (
 goto end
)

:yes

echo -------------------------------------
echo;
rem makecab実行時の指令ファイル名を準備
set directivefilename=directive.ddf

rem makecab実行時の指令ファイルを作成
echo .Set CabinetNameTemplate=%fragmentfilename% >%directivefilename%
echo .Set DiskDirectoryTemplate="%~dp0%dirname%" >>%directivefilename% >>%directivefilename%
echo .Set Cabinet=on >>%directivefilename%
echo .Set MaxDiskSize=%fragmentsize% >>%directivefilename%
echo %~f1 >>%directivefilename%

rem 分割コマンド実行
makecab /f %directivefilename% /L %dirname%

rem 一時作成ファイル削除
del %directivefilename%

rem 自動生成ファイル削除
del setup.inf
del setup.rpt

set %~dp0=
set output=%~dp0%dirname%\ファイル結合.bat
rem 結合用バッチファイル作成
echo @echo off > %output%
echo echo %filename%の復元を開始します。 >> %output%
echo set hash_before=%hash_before% >> %output%
echo %WINDIR%\system32\extrac32.exe /e /a /y %fragmentfilename2% >> %output%
echo echo 結合が完了しました。 >> %output%
echo echo ハッシュ値チェックを開始します。 >> %output%
echo echo; >> %output%
echo cd %%~dp0 >> %output%
echo for /f "usebackq skip=1 delims=" %%%%A in (`certutil -hashfile %filename%`) do ( >> %output%
echo     set hash_after=%%%%A >> %output%
echo     goto exitfor2 >> %output%
echo ) >> %output%
echo :exitfor2 >> %output%
echo echo ------------------------------------- >> %output%
echo echo 分割前ハッシュ値：%hash_before% >> %output%
echo echo 結合後ハッシュ値：%%hash_after%% >> %output%
echo echo ------------------------------------- >> %output%
echo if %hash_before%==%%hash_after%% ( >> %output%
echo     echo ハッシュ値が一致しました。終了します。 >> %output%
echo ) else ( >> %output%
echo     echo ハッシュ値に差異がありました。ファイル分割・結合どちらかが正しく行えていません。 >> %output%
echo ) >> %output%
echo pause >> %output%

rem 分割フォルダを表示
start %~dp0%dirname%
echo;
echo -------------------------------------
echo ファイル分割が完了しました。終了します。
pause
goto end


:end