【ExcelVBA】リモートデスクトップのログインを自動化。Excelの表からワンクリックでRDP接続。

'処理の待ち時間を待機する準備
Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Public Type 列の型
    SV_IP As Long
    SV_ID As Long
    SV_PW As Long
    GW_IP As Long
    GW_ID As Long
    GW_PW As Long
End Type
Public Type 接続情報の型
    SV_IP As String
    SV_ID As String
    SV_PW As String
    GW_IP As String
    GW_ID As String
    GW_PW As String
End Type

Dim ベースGW_IP, ベースGW_ID, ベースGW_PW As String

Sub ベースGW情報を設定()
    ベースGW_IP = InputBox("ゲートウェイのIPを入力してください。")
    ベースGW_ID = InputBox("ゲートウェイのIDを入力してください。")
    ベースGW_PW = InputBox("ゲートウェイのPWを入力してください。")
    MsgBox "ゲートウェイ情報の設定が完了しました。"
End Sub

Sub RDP接続()
    'アカウントリストに存在しないゲートウェイを使うか選択
    ベースGW使用 = False '使う=True 使わない=False
    
    Dim 列 As 列の型
    'サーバのIPの列番号
    列.SV_IP = 2
    'サーバのユーザ名の列番号
    列.SV_ID = 3
    'サーバのパスワードの列番号
    列.SV_PW = 4
    'ゲートウェイのIPの列番号
    列.GW_IP = 5
    'ゲートウェイのユーザ名の列番号
    列.GW_ID = 6
    'ゲートウェイのパスワードの列番号
    列.GW_PW = 7
    
    Dim 接続情報 As 接続情報の型
    With ActiveWorkbook.ActiveSheet
        選択行 = Selection.Row
        接続情報.SV_IP = .Cells(選択行, 列.SV_IP)
        接続情報.SV_ID = .Cells(選択行, 列.SV_ID)
        接続情報.SV_PW = .Cells(選択行, 列.SV_PW)
        接続情報.GW_IP = .Cells(選択行, 列.GW_IP)
        接続情報.GW_ID = .Cells(選択行, 列.GW_ID)
        接続情報.GW_PW = .Cells(選択行, 列.GW_PW)
    End With
        
    'サーバ接続情報が足りない場合は入力画面を表示
    If 接続情報.SV_IP = "" Then
        MsgBox "IPが設定されていません。処理を終了します。"
        Exit Sub
    End If
    If 接続情報.SV_ID = "" Then
        接続情報.SV_ID = InputBox("サーバのユーザー名を入力してください。")
    End If
    If 接続情報.SV_PW = "" Then
        接続情報.SV_PW = InputBox("サーバのパスワードを入力してください。")
    End If
    
    'ベースGWが有の場合、ベースGWを使うか確認する画面を表示
    If ベースGW使用 = True Then
        If MsgBox("ベースGWを使用しますか？", vbYesNo + vbQuestion, "確認") = vbYes Then
            接続情報.GW_IP = ベースGW_IP
            接続情報.GW_ID = ベースGW_ID
            接続情報.GW_PW = ベースGW_PW
        End If
    Else
    'ゲートウェイ接続情報が足りない場合は入力画面を表示
        If 接続情報.GW_IP <> "" And 接続情報.GW_ID = "" Then
            接続情報.GW_ID = InputBox("ゲートウェイのユーザー名を入力してください。")
        End If
        If 接続情報.GW_IP <> "" And 接続情報.GW_PW = "" Then
            接続情報.GW_PW = InputBox("ゲートウェイのパスワードを入力してください。")
        End If
    End If
    
    '処理の待ち時間を設定
    待機時間_処理待ち = 2000
    待機時間_入力 = 100
    
    'RDPを起動
    rc = Shell("mstsc.exe", vbNormalFocus)
    Call Sleep(待機時間_処理待ち)
    Application.SendKeys 接続情報.SV_IP, True
    Call Sleep(待機時間_入力)
    Application.SendKeys "%{o}", True
    Call Sleep(待機時間_入力)
    Application.SendKeys "{TAB}", True
    Call Sleep(待機時間_入力)
    Application.SendKeys 接続情報.SV_ID, True
    Call Sleep(待機時間_入力)
    
    'ゲートウェイタブ
    Application.SendKeys "+{TAB}", True
    Call Sleep(待機時間_入力)
    Application.SendKeys "+{TAB}", True
    Call Sleep(待機時間_入力)
    Application.SendKeys "{RIGHT 5}", True
    Call Sleep(待機時間_入力)
    Application.SendKeys "%{s}", True
    Call Sleep(待機時間_入力)
    
    If 接続情報.GW_IP <> "" Then
        'ゲートウェイ情報
        Application.SendKeys "%{u}", True
        Call Sleep(待機時間_入力)
        Application.SendKeys "%{s}", True
        Call Sleep(待機時間_入力)
        Application.SendKeys 接続情報.GW_IP, True
        Call Sleep(待機時間_入力)
        Application.SendKeys "~", True
        Call Sleep(待機時間_入力)
        
        '接続ボタン
        Application.SendKeys "%{n}", True
        Call Sleep(待機時間_処理待ち)
            
        'ゲートウェイユーザー・パスワード入力
        Application.SendKeys 接続情報.GW_ID, True
        Call Sleep(待機時間_入力)
        Application.SendKeys "{TAB}", True
        Call Sleep(待機時間_入力)
        Application.SendKeys 接続情報.GW_PW, True
        Call Sleep(待機時間_入力)
        Application.SendKeys "~", True
        Call Sleep(待機時間_処理待ち)
    Else
        Application.SendKeys "%{d}", True
        Call Sleep(待機時間_入力)
        Application.SendKeys "~", True
        Call Sleep(待機時間_入力)
        '接続ボタン
        Application.SendKeys "%{n}", True
        Call Sleep(待機時間_処理待ち)
    End If
    
    'サーバパスワード入力
    Application.SendKeys 接続情報.SV_PW, True
    Call Sleep(待機時間_入力)
    Application.SendKeys "~", True
    Call Sleep(待機時間_入力)
End Sub